MATIC Price: $0.529608 (+0.81%)
Gas: 31.6 GWei
 

Overview

MATIC Balance

Polygon PoS Chain LogoPolygon PoS Chain LogoPolygon PoS Chain Logo0 MATIC

MATIC Value

$0.00

Token Holdings

Multichain Info

No addresses found
Transaction Hash
Method
Block
From
To
Exec Transaction578199782024-06-06 3:20:2448 days ago1717644024IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0024698730.00000009
Exec Transaction578199342024-06-06 3:18:5048 days ago1717643930IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0159621930.0000001
Exec Transaction578195212024-06-06 3:03:0648 days ago1717642986IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0024659130.00000077
Exec Transaction578193952024-06-06 2:58:0648 days ago1717642686IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0133984830.00000147
Exec Transaction578193652024-06-06 2:57:0248 days ago1717642622IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0025775130.00000139
Exec Transaction578193432024-06-06 2:55:4248 days ago1717642542IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0018851130.00000117
Exec Transaction577714532024-06-04 20:57:1949 days ago1717534639IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0349871446.00000002
Exec Transaction577714402024-06-04 20:56:5349 days ago1717534613IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0307731240.00000002
Exec Transaction577713922024-06-04 20:55:1149 days ago1717534511IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0027448530.00000003
Exec Transaction577713282024-06-04 20:52:5549 days ago1717534375IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0112491630.00000002
Exec Transaction577712812024-06-04 20:51:1549 days ago1717534275IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0027448530.00000002
Exec Transaction577712512024-06-04 20:50:1149 days ago1717534211IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0670727983.00000003
Exec Transaction577712042024-06-04 20:48:3149 days ago1717534111IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.006481875.00000003
Exec Transaction577711422024-06-04 20:46:1949 days ago1717533979IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.1178460775.00000002
Exec Transaction577711282024-06-04 20:45:4949 days ago1717533949IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0942655959
Exec Transaction577711162024-06-04 20:45:2349 days ago1717533923IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0714051549
Exec Transaction577710872024-06-04 20:44:2149 days ago1717533861IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0025840530.00000002
Exec Transaction577710592024-06-04 20:43:2349 days ago1717533803IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0263127348.00000002
Exec Transaction577710452024-06-04 20:42:5349 days ago1717533773IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0219226439.00000002
Exec Transaction577710062024-06-04 20:41:2949 days ago1717533689IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0027448530.00000002
Exec Transaction577709472024-06-04 20:39:2549 days ago1717533565IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0102656638.00000002
Exec Transaction577708942024-06-04 20:37:3149 days ago1717533451IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0029360730.00000002
Exec Transaction577708002024-06-04 20:34:1349 days ago1717533253IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0624832641.00000003
Exec Transaction577707852024-06-04 20:33:4149 days ago1717533221IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.0464601630.00000003
Exec Transaction577707582024-06-04 20:32:4349 days ago1717533163IN
0xd9ba1D5D...C91a99C9D
0 MATIC0.053205630.00000002
View all transactions

Latest 1 internal transaction

Parent Transaction Hash Block From To
442185232023-06-22 20:14:22397 days ago1687464862  Contract Creation0 MATIC
Loading...
Loading

Similar Match Source Code
This contract matches the deployed Bytecode of the Source Code for Contract 0xb412684F...aB3ae124D
The constructor portion of the code might be different and could alter the actual behaviour of the contract

Contract Name:
GnosisSafeProxy

Compiler Version
v0.7.6+commit.7338295f

Optimization Enabled:
No with 200 runs

Other Settings:
default evmVersion, GNU LGPLv3 license
/**
 *Submitted for verification at polygonscan.com on 2021-07-05
*/

/**
 *Submitted for verification at polygonscan.com on 2021-06-16
*/

// SPDX-License-Identifier: LGPL-3.0-only
pragma solidity >=0.7.0 <0.9.0;

/// @title IProxy - Helper interface to access masterCopy of the Proxy on-chain
/// @author Richard Meissner - <[email protected]>
interface IProxy {
    function masterCopy() external view returns (address);
}

/// @title GnosisSafeProxy - Generic proxy contract allows to execute all transactions applying the code of a master contract.
/// @author Stefan George - <[email protected]>
/// @author Richard Meissner - <[email protected]>
contract GnosisSafeProxy {
    // singleton always needs to be first declared variable, to ensure that it is at the same location in the contracts to which calls are delegated.
    // To reduce deployment costs this variable is internal and needs to be retrieved via `getStorageAt`
    address internal singleton;

    /// @dev Constructor function sets address of singleton contract.
    /// @param _singleton Singleton address.
    constructor(address _singleton) {
        require(_singleton != address(0), "Invalid singleton address provided");
        singleton = _singleton;
    }

    /// @dev Fallback function forwards all transactions and returns all received return data.
    fallback() external payable {
        // solhint-disable-next-line no-inline-assembly
        assembly {
            let _singleton := and(sload(0), 0xffffffffffffffffffffffffffffffffffffffff)
            // 0xa619486e == keccak("masterCopy()"). The value is right padded to 32-bytes with 0s
            if eq(calldataload(0), 0xa619486e00000000000000000000000000000000000000000000000000000000) {
                mstore(0, _singleton)
                return(0, 0x20)
            }
            calldatacopy(0, 0, calldatasize())
            let success := delegatecall(gas(), _singleton, 0, calldatasize(), 0, 0)
            returndatacopy(0, 0, returndatasize())
            if eq(success, 0) {
                revert(0, returndatasize())
            }
            return(0, returndatasize())
        }
    }
}

/// @title Proxy Factory - Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
/// @author Stefan George - <[email protected]>
contract GnosisSafeProxyFactory {
    event ProxyCreation(GnosisSafeProxy proxy, address singleton);

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param singleton Address of singleton contract.
    /// @param data Payload for message call sent to new proxy contract.
    function createProxy(address singleton, bytes memory data) public returns (GnosisSafeProxy proxy) {
        proxy = new GnosisSafeProxy(singleton);
        if (data.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(data, 0x20), mload(data), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, singleton);
    }

    /// @dev Allows to retrieve the runtime code of a deployed Proxy. This can be used to check that the expected Proxy was deployed.
    function proxyRuntimeCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).runtimeCode;
    }

    /// @dev Allows to retrieve the creation code used for the Proxy deployment. With this it is easily possible to calculate predicted address.
    function proxyCreationCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).creationCode;
    }

    /// @dev Allows to create new proxy contact using CREATE2 but it doesn't run the initializer.
    ///      This method is only meant as an utility to be called from other methods
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function deployProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) internal returns (GnosisSafeProxy proxy) {
        // If the initializer changes the proxy address should change too. Hashing the initializer data is cheaper than just concatinating it
        bytes32 salt = keccak256(abi.encodePacked(keccak256(initializer), saltNonce));
        bytes memory deploymentData = abi.encodePacked(type(GnosisSafeProxy).creationCode, uint256(uint160(_singleton)));
        // solhint-disable-next-line no-inline-assembly
        assembly {
            proxy := create2(0x0, add(0x20, deploymentData), mload(deploymentData), salt)
        }
        require(address(proxy) != address(0), "Create2 call failed");
    }

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function createProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) public returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        if (initializer.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(initializer, 0x20), mload(initializer), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, _singleton);
    }

    /// @dev Allows to create new proxy contact, execute a message call to the new proxy and call a specified callback within one transaction
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    /// @param callback Callback that will be invoced after the new proxy contract has been successfully deployed and initialized.
    function createProxyWithCallback(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce,
        IProxyCreationCallback callback
    ) public returns (GnosisSafeProxy proxy) {
        uint256 saltNonceWithCallback = uint256(keccak256(abi.encodePacked(saltNonce, callback)));
        proxy = createProxyWithNonce(_singleton, initializer, saltNonceWithCallback);
        if (address(callback) != address(0)) callback.proxyCreated(proxy, _singleton, initializer, saltNonce);
    }

    /// @dev Allows to get the address for a new proxy contact created via `createProxyWithNonce`
    ///      This method is only meant for address calculation purpose when you use an initializer that would revert,
    ///      therefore the response is returned with a revert. When calling this method set `from` to the address of the proxy factory.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function calculateCreateProxyWithNonceAddress(
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        revert(string(abi.encodePacked(proxy)));
    }
}

interface IProxyCreationCallback {
    function proxyCreated(
        GnosisSafeProxy proxy,
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external;
}

Contract Security Audit

Contract ABI

[{"inputs":[{"internalType":"address","name":"_singleton","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"stateMutability":"payable","type":"fallback"}]

Deployed Bytecode

0x608060405273ffffffffffffffffffffffffffffffffffffffff600054167fa619486e0000000000000000000000000000000000000000000000000000000060003514156050578060005260206000f35b3660008037600080366000845af43d6000803e60008114156070573d6000fd5b3d6000f3fea2646970667358221220d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b955264736f6c63430007060033

Deployed Bytecode Sourcemap

598:1528:0:-:0;;;1450:42;1446:1;1440:8;1436:57;1630:66;1626:1;1613:15;1610:87;1607:2;;;1727:10;1724:1;1717:21;1766:4;1763:1;1756:15;1607:2;1819:14;1816:1;1813;1800:34;1917:1;1914;1898:14;1895:1;1883:10;1876:5;1863:56;1954:16;1951:1;1948;1933:38;2000:1;1991:7;1988:14;1985:2;;;2032:16;2029:1;2022:27;1985:2;2088:16;2085:1;2078:27

Swarm Source

ipfs://d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b9552

Block Transaction Gas Used Reward
view all blocks produced

Block Uncle Number Difficulty Gas Used Reward
View All Uncles
Loading...
Loading
Loading...
Loading

Validator Index Block Amount
View All Withdrawals

Transaction Hash Block Value Eth2 PubKey Valid
View All Deposits
Chain Token Portfolio % Price Amount Value
MATIC63.77%$1.874,954.1158$9,264.2
MATIC12.56%$0.5322093,427.925$1,824.37
MATIC12.25%$3,436.030.518$1,779.73
MATIC2.66%<$0.00000121,987,038,539.5954$386.97
MATIC1.26%$0.999684183.1311$183.07
MATIC0.94%$0.999213137.2341$137.13
MATIC0.92%$0.0404713,319.008$134.32
MATIC0.87%$65,7990.00192731$126.82
MATIC0.76%$0.153976718.9291$110.7
MATIC0.51%$0.99921374.0974$74.04
MATIC0.41%$0.59632799.7939$59.51
MATIC0.41%$0.6901485.688$59.14
MATIC0.38%$155.7835$55.84
MATIC0.30%$4,032.450.0109$43.94
MATIC0.27%$13.752.8955$39.81
MATIC0.23%$0.056916590.3604$33.6
MATIC0.21%$0.26259118.6499$31.16
MATIC0.21%$2.6911.231$30.21
MATIC0.18%$92.670.2828$26.2
MATIC0.15%$0.00000214,941,598.4433$22.44
MATIC0.13%$0.48947739.7876$19.48
MATIC0.11%$0.99605716.4017$16.34
MATIC0.11%$1.0714.8757$15.93
MATIC0.11%$1.0515.1292$15.93
MATIC0.09%$91.210.1488$13.57
MATIC0.08%$0.0055082,171.7574$11.96
MATIC0.06%$0.020409399.2736$8.15
MATIC0.02%$0.003253738.3356$2.4
MATIC<0.01%$0.0415686.1519$0.2557
MATIC<0.01%$0.9954470.2462$0.2451
MATIC<0.01%$0.9930120.2227$0.2211
MATIC<0.01%$3,434.680.00003099$0.1064
[ Download: CSV Export  ]
[ Download: CSV Export  ]

A contract address hosts a smart contract, which is a set of code stored on the blockchain that runs when predetermined conditions are met. Learn more about addresses in our Knowledge Base.