// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {Initializable} from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import {Pausable} from "@openzeppelin/contracts/security/Pausable.sol";
import {AdminPrivileges} from "./AdminPrivileges.sol";
import {AdminWallet} from "./AdminWallet.sol";
import {CappedCrowdsaleHelper} from "./CappedCrowdsaleHelper.sol";
import {Crowdsale} from "./Crowdsale.sol";
import {LotsCrowdsaleHelper} from "./LotsCrowdsaleHelper.sol";
import {TimedCrowdsaleHelper} from "./TimedCrowdsaleHelper.sol";
import {WhitelistCrowdsaleHelper} from "./WhitelistCrowdsaleHelper.sol";
import {IFactoryImplementation} from "./interfaces/IFactoryImplementation.sol"; // solhint-disable-line no-unused-import
import {ILaunchpadCrowdsaleDefault} from "./interfaces/ILaunchpadCrowdsaleDefault.sol";

/**
 * @title LaunchpadCrowdsaleDefault
 * @author Tim Loh
 * @notice Provides default implementation of launchpad crowdsale interface
 */
contract LaunchpadCrowdsaleDefault is
    Initializable,
    Pausable,
    AdminPrivileges,
    AdminWallet,
    CappedCrowdsaleHelper,
    LotsCrowdsaleHelper,
    TimedCrowdsaleHelper,
    WhitelistCrowdsaleHelper,
    Crowdsale,
    ILaunchpadCrowdsaleDefault
{
    uint256 public constant PERCENT_100_WEI = 100 ether;
    uint256 public constant SECONDS_IN_DAY = 86400;
    uint256 public constant WHITELIST_BATCH_MAX_NUM = 200;

    constructor() {
        _disableInitializers();
    }

    /**
     * @param tokenWeiCap Max wei amount of tokens to be sold
     * @param weiLotSize Lot size in wei
     * @param paymentTokensInfo The payment token address, decimals and rate
     * @param isNonEvmAddressRequired True if require non-EVM address to participate in crowdsale
     * @param allowNativeTokenPayment True if native token is allowed for payment
     * @param timeframe Crowdsale opening and closing times
     * @param backofficeAdminAddress The address that will be assigned the backoffice role admin role and backoffice
     *                               contract admin role
     */
    function initialize(
        uint256 tokenWeiCap,
        uint256 weiLotSize,
        PaymentTokenInfo[] memory paymentTokensInfo,
        bool isNonEvmAddressRequired,
        bool allowNativeTokenPayment,
        Timeframe memory timeframe,
        address backofficeAdminAddress
    ) public virtual initializer {
        __LaunchpadCrowdsaleDefault_init(
            tokenWeiCap,
            weiLotSize,
            paymentTokensInfo,
            isNonEvmAddressRequired,
            allowNativeTokenPayment,
            timeframe,
            backofficeAdminAddress
        );
    }

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function __LaunchpadCrowdsaleDefault_init(
        // solhint-disable-previous-line func-name-mixedcase
        uint256 tokenWeiCap,
        uint256 weiLotSize,
        PaymentTokenInfo[] memory paymentTokensInfo,
        bool isNonEvmAddressRequired,
        bool allowNativeTokenPayment,
        Timeframe memory timeframe,
        address backofficeAdminAddress
    ) internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
        __CappedCrowdsaleHelper_init_unchained(tokenWeiCap);
        __LotsCrowdsaleHelper_init_unchained(weiLotSize);
        __TimedCrowdsaleHelper_init_unchained(timeframe);
        __Crowdsale_init_unchained(paymentTokensInfo, isNonEvmAddressRequired, allowNativeTokenPayment);
        __LaunchpadCrowdsaleDefault_init_unchained(backofficeAdminAddress);
    }

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function __LaunchpadCrowdsaleDefault_init_unchained(
        // solhint-disable-previous-line func-name-mixedcase
        address backofficeAdminAddress
    ) internal onlyInitializing {
        require(backofficeAdminAddress != address(0), "LCD: backoffice admin");

        _setRoleAdmin(BACKOFFICE_ROLE_ADMIN_ROLE, BACKOFFICE_ROLE_ADMIN_ROLE);
        _setRoleAdmin(BACKOFFICE_GOVERNANCE_ROLE, BACKOFFICE_ROLE_ADMIN_ROLE);
        _setRoleAdmin(BACKOFFICE_CONTRACT_ADMIN_ROLE, BACKOFFICE_ROLE_ADMIN_ROLE);

        _grantRole(BACKOFFICE_ROLE_ADMIN_ROLE, backofficeAdminAddress);
        _grantRole(BACKOFFICE_GOVERNANCE_ROLE, backofficeAdminAddress);
        _grantRole(BACKOFFICE_CONTRACT_ADMIN_ROLE, backofficeAdminAddress);

        _setAdminWallet(backofficeAdminAddress);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    // solhint-disable-next-line ordering
    function addWhitelistedAccount(address account, uint256 weiAmount)
        external
        virtual
        override
        onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE)
    {
        _addWhitelistedAccount(account, weiAmount);
    }

    function addWhitelistedAccounts(
        address[] memory accounts,
        uint256[] memory weiAmounts
    ) external virtual override onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE) {
        require(accounts.length > 0, "LCD: empty");
        require(
            accounts.length <= WHITELIST_BATCH_MAX_NUM,
            "LCD: exceed max"
        );
        require(
            weiAmounts.length == accounts.length,
            "LCD: different length"
        );

        for (uint256 i = 0; i < accounts.length; i++) {
            _addWhitelistedAccount(accounts[i], weiAmounts[i]);
        }
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function cancelCrowdsaleWindow() external virtual override onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE) {
        _cancelCrowdsaleWindow();
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function extendCrowdsaleWindow(uint256 newEndTimestamp)
        external
        virtual
        override
        onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE)
    {
        _extendCrowdsaleWindow(newEndTimestamp);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function participateCrowdsaleWithErc20(
        address paymentToken,
        uint256 lots,
        string calldata nonEvmAddress
    ) external virtual override {
        require(lots > 0, "LCD: zero lots");

        uint256 paymentWeiAmount = lotsPaymentWeiAmountFor(paymentToken, lots);

        _participateCrowdsaleFor(msg.sender, paymentToken, paymentWeiAmount, nonEvmAddress);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function participateCrowdsaleWithNative(
        string calldata nonEvmAddress
    ) external payable virtual override {
        require(msg.value > 0, "LCD: zero native tokens");

        uint256 numLots = numLotsForPayment(NATIVE_TOKEN_ADDRESS, msg.value);
        require(numLots > 0, "LCD: zero lots");

        uint256 paymentWeiAmount = lotsPaymentWeiAmountFor(NATIVE_TOKEN_ADDRESS, numLots);

        _participateCrowdsaleFor(msg.sender, NATIVE_TOKEN_ADDRESS, paymentWeiAmount, nonEvmAddress);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function pauseContract() external virtual override onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE) {
        _pause();
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function removeWhitelistedAccount(address account)
        external
        virtual
        override
        onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE)
    {
        _removeWhitelistedAccount(account);
    }

    function removeWhitelistedAccounts(address[] memory accounts)
        external
        virtual
        override
        onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE)
    {
        require(accounts.length > 0, "LCD: empty");
        require(
            accounts.length <= WHITELIST_BATCH_MAX_NUM,
            "LCD: exceed max"
        );

        for (uint256 i = 0; i < accounts.length; i++) {
            _removeWhitelistedAccount(accounts[i]);
        }
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function setAdminWallet(address newWallet) external virtual override onlyRole(BACKOFFICE_GOVERNANCE_ROLE) {
        _setAdminWallet(newWallet);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function setCrowdsaleTokenWeiCap(uint256 newTokenWeiCap)
        external
        virtual
        override
        onlyBeforeCrowdsaleStart
        onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE)
    {
        _setCrowdsaleTokenWeiCap(newTokenWeiCap);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function setCrowdsaleWindow(
        uint256 startTimestamp,
        uint256 endTimestamp
    ) external virtual override onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE) {
        _setCrowdsaleWindow(startTimestamp, endTimestamp);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function setLotWeiSize(uint256 newLotWeiSize)
        external
        virtual
        override
        onlyBeforeCrowdsaleStart
        onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE)
    {
        _setLotWeiSize(newLotWeiSize);
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function unpauseContract() external virtual override onlyRole(BACKOFFICE_CONTRACT_ADMIN_ROLE) {
        _unpause();
    }

    /**
     * @inheritdoc IFactoryImplementation
     */
    function factoryImplementationType() external view virtual override returns (uint256 implementationType) {
        implementationType = 0xa07f0b4ee126afd09bbd8d87840604d43563753e8be9a86560e0409d1d864308;
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function getRemainderWeiCrowdsaleTokens() external view override returns (uint256 remainderTokens) {
        remainderTokens = crowdsaleTokenWeiCap() - crowdsaleTokensWeiSold;
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function lotsPaymentWeiAmountFor(
        address paymentToken,
        uint256 lots
    ) public view virtual override returns (uint256 paymentWeiAmount) {
        uint256 tokenWeiAmount = totalWeiAmountFor(lots);
        uint256 paymentRate = _paymentRateFor(paymentToken);

        paymentWeiAmount = tokenWeiAmount * paymentRate / TOKEN_SELLING_SCALE;
    }

    /**
     * @inheritdoc ILaunchpadCrowdsaleDefault
     */
    function numLotsForPayment(
        address paymentToken,
        uint256 paymentWeiAmount
    ) public view virtual override returns (uint256 numLots) {
        uint256 purchaseWeiAmount = _purchaseWeiAmountFor(paymentToken, paymentWeiAmount);
        numLots = purchaseWeiAmount / lotWeiSize();
    }

    /**
     * @dev Extend parent behavior to update purchased amount of tokens by beneficiary.
     * @param beneficiary Token purchaser
     * @param paymentToken ERC20 payment token address
     * @param paymentWeiAmount Amount in wei of ERC20 payment token
     * @param purchaseWeiAmount Number of tokens to be purchased in wei
     */
    function _updatePurchasingState(
        address beneficiary,
        address paymentToken,
        uint256 paymentWeiAmount,
        uint256 purchaseWeiAmount
    ) internal virtual override {
        super._updatePurchasingState(
            beneficiary,
            paymentToken,
            paymentWeiAmount,
            purchaseWeiAmount
        );

        _updateBeneficiaryTokensPurchased(beneficiary, purchaseWeiAmount);
    }

    /**
     * @param beneficiary Token beneficiary
     * @param paymentToken ERC20 payment token address
     * @param paymentWeiAmount Amount of wei contributed
     * @param purchaseWeiAmount Number of tokens to be purchased in wei
     */
    function _preValidatePurchase(
        address beneficiary,
        address paymentToken,
        uint256 paymentWeiAmount,
        uint256 purchaseWeiAmount
    )
        internal
        view
        virtual
        override
        whenNotPaused
        onlyWhileCrowdsaleOpen
        crowdsaleTokenCapNotExceeded(crowdsaleTokensWeiSold, purchaseWeiAmount)
        isWhitelisted(beneficiary)
        beneficiaryCapNotExceeded(beneficiary, purchaseWeiAmount)
    {
        super._preValidatePurchase(
            beneficiary,
            paymentToken,
            paymentWeiAmount,
            purchaseWeiAmount
        );
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/Address.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!Address.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {AccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";
import {IAdminPrivileges} from "./interfaces/IAdminPrivileges.sol";

/**
 * @title AdminPrivileges
 * @author Tim Loh
 * @notice Provides admin privileges role definitions that are inherited by other contracts
 */
contract AdminPrivileges is AccessControl, IAdminPrivileges {
    bytes32 public constant BACKOFFICE_ROLE_ADMIN_ROLE = keccak256("BACKOFFICE_ROLE_ADMIN_ROLE");
    bytes32 public constant BACKOFFICE_GOVERNANCE_ROLE = keccak256("BACKOFFICE_GOVERNANCE_ROLE");
    bytes32 public constant BACKOFFICE_CONTRACT_ADMIN_ROLE = keccak256("BACKOFFICE_CONTRACT_ADMIN_ROLE");

    bytes32 public constant TENANT_ROLE_ADMIN_ROLE = keccak256("TENANT_ROLE_ADMIN_ROLE");
    bytes32 public constant TENANT_GOVERNANCE_ROLE = keccak256("TENANT_GOVERNANCE_ROLE");
    bytes32 public constant TENANT_CONTRACT_ADMIN_ROLE = keccak256("TENANT_CONTRACT_ADMIN_ROLE");
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {IAdminWallet} from "./interfaces/IAdminWallet.sol";

/**
 * @title AdminWallet
 * @author Tim Loh
 * @notice Provides an implementation of the admin wallet interface that is inherited by other contracts
 */
contract AdminWallet is IAdminWallet {
    address private _adminWallet;

    /**
     * @inheritdoc IAdminWallet
     */
    function adminWallet() public view virtual override returns (address) {
        return _adminWallet;
    }

    /**
     * @dev Change admin wallet that will receive the funds to a new wallet address
     * @param newWallet The new admin wallet address
     */
    function _setAdminWallet(address newWallet) internal virtual {
        require(newWallet != address(0), "AdminWallet: new wallet");

        address oldWallet = _adminWallet;
        _adminWallet = newWallet;

        emit AdminWalletChanged(oldWallet, newWallet, msg.sender);
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {Initializable} from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import {ICappedCrowdsaleHelper} from "./interfaces/ICappedCrowdsaleHelper.sol";

/**
 * @title CappedCrowdsaleHelper
 * @author Tim Loh
 * @notice Helper for crowdsale with a limit for total tokens sold
 */
contract CappedCrowdsaleHelper is Initializable, ICappedCrowdsaleHelper {
    uint256 private _crowdsaleTokenWeiCap;

    modifier crowdsaleTokenCapNotExceeded(uint256 tokensWeiSold, uint256 tokenWeiAmount) {
        require(
            tokensWeiSold + tokenWeiAmount <= _crowdsaleTokenWeiCap,
            "CCH: cap exceeded"
        );
        _;
    }

    constructor() {
        _disableInitializers();
    }

    /**
     * @param tokenWeiCap Max wei amount of tokens to be sold
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function __CappedCrowdsaleHelper_init_unchained(
        // solhint-disable-previous-line func-name-mixedcase
        uint256 tokenWeiCap
    ) internal onlyInitializing {
        require(tokenWeiCap > 0, "CCH: zero cap");

        _crowdsaleTokenWeiCap = tokenWeiCap;
    }

    /**
     * @inheritdoc ICappedCrowdsaleHelper
     */
    // solhint-disable-next-line ordering
    function crowdsaleTokenCapReached(uint256 tokensWeiSold)
        external
        view
        virtual
        override
        returns (bool tokenCapReached)
    {
        tokenCapReached = (tokensWeiSold >= _crowdsaleTokenWeiCap);
    }

    /**
     * @inheritdoc ICappedCrowdsaleHelper
     */
    function crowdsaleTokenWeiCap() public view virtual override returns (uint256 tokenWeiCap) {
        tokenWeiCap = _crowdsaleTokenWeiCap;
    }

    /**
     * @dev Change max wei amount of tokens to be sold
     * @param newTokenWeiCap The new token cap in wei of the crowdsale
     */
    function _setCrowdsaleTokenWeiCap(uint256 newTokenWeiCap) internal virtual {
        require(newTokenWeiCap > 0, "CCH: zero new cap");

        uint256 oldTokenWeiCap = _crowdsaleTokenWeiCap;
        _crowdsaleTokenWeiCap = newTokenWeiCap;

        emit CrowdsaleCapChanged(msg.sender, newTokenWeiCap, oldTokenWeiCap);
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {Initializable} from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import {Address} from "@openzeppelin/contracts/utils/Address.sol";
import {IERC20, TransferErc20} from "./libraries/TransferErc20.sol";
import {AdminWallet} from "./AdminWallet.sol";
import {ReentrancyGuard} from "./ReentrancyGuard.sol";
import {ICrowdsale} from "./interfaces/ICrowdsale.sol";

/**
 * @title Crowdsale
 * @author Tim Loh
 * @dev Crowdsale is a base contract for managing a token crowdsale, allowing investors to
 * purchase tokens with ERC20 or native tokens. This contract implements such functionality
 * in its most fundamental form and can be extended to provide additional functionality and/or
 * custom behavior.
 * The external interface represents the basic interface for purchasing tokens, and conforms
 * the base architecture for crowdsales. It is *not* intended to be modified / overridden.
 * The internal interface conforms the extensible and modifiable surface of crowdsales. Override
 * the methods to add functionality. Consider using 'super' where appropriate to concatenate
 * behavior.
 */
contract Crowdsale is Initializable, ReentrancyGuard, AdminWallet, ICrowdsale {
    using TransferErc20 for IERC20;

    uint256 public constant MAX_NUM_PAYMENT_TOKENS = 10;
    address public constant NATIVE_TOKEN_ADDRESS = address(0);
    uint256 public constant TOKEN_MAX_DECIMALS = 18;
    uint256 public constant TOKEN_SELLING_SCALE = 10**TOKEN_MAX_DECIMALS;

    // True if native token is allowed for payment
    bool public allowNativePaymentToken;

    // Wei amount of crowdsale tokens sold
    uint256 public crowdsaleTokensWeiSold;

    // True if require non-EVM address to participate in crowdsale
    bool public requireNonEvmAddress;

    // Payment tokens
    address[] private _paymentTokens;

    // Indicates whether token is acceptable for payment
    mapping(address => bool) private _isPaymentTokens;

    // Payment token decimals
    mapping(address => uint256) private _paymentDecimals;

    // How many weis one token costs for each payment token
    mapping(address => uint256) private _paymentRates;

    // Amount of wei raised for each payment token
    mapping(address => uint256) private _weiRaised;

    constructor() {
        _disableInitializers();
    }

    /**
     * @dev Rates will denote how many weis one token costs for each payment token.
     * For USDC or USDT payment token which has 6 decimals, minimum rate will
     * be 1000000000000 which will correspond to a price of USD0.000001 per token.
     * @param paymentTokensInfo Addresses, decimals, rates and lot sizes of tokens acceptable for payment
     * @param isNonEvmAddressRequired True if require non-EVM address to participate in crowdsale
     * @param allowNativeTokenPayment True if native token is allowed for payment
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function __Crowdsale_init_unchained(
        // solhint-disable-previous-line func-name-mixedcase
        PaymentTokenInfo[] memory paymentTokensInfo,
        bool isNonEvmAddressRequired,
        bool allowNativeTokenPayment
    ) internal onlyInitializing {
        require(paymentTokensInfo.length > 0, "Crowdsale: zero payment tokens");
        require(
            paymentTokensInfo.length < MAX_NUM_PAYMENT_TOKENS,
            "Crowdsale: max payment tokens"
        );

        for (uint256 i = 0; i < paymentTokensInfo.length; i++) {
            uint256 paymentDecimals = paymentTokensInfo[i].paymentDecimals;
            require(
                paymentDecimals <= TOKEN_MAX_DECIMALS,
                "Crowdsale: decimals exceed 18"
            );
            address paymentToken = paymentTokensInfo[i].paymentToken;
            require(
                paymentToken != NATIVE_TOKEN_ADDRESS ||
                    (allowNativeTokenPayment &&
                        paymentDecimals == TOKEN_MAX_DECIMALS),
                "Crowdsale: zero payment token"
            );
            uint256 paymentRate = paymentTokensInfo[i].paymentRate;
            require(paymentRate > 0, "Crowdsale: zero rate");

            _isPaymentTokens[paymentToken] = true;
            _paymentTokens.push(paymentToken);
            _paymentDecimals[paymentToken] = paymentDecimals;
            _paymentRates[paymentToken] = paymentRate;
        }

        allowNativePaymentToken = allowNativeTokenPayment;
        requireNonEvmAddress = isNonEvmAddressRequired;
    }

    /**
     * @inheritdoc ICrowdsale
     */
    // solhint-disable-next-line ordering
    function getPaymentTokenAddresses()
        external
        view
        override
        returns (address[] memory tokenList)
    {
        tokenList = _paymentTokens;
    }

    /**
     * @inheritdoc ICrowdsale
     */
    function paymentDecimalsFor(address paymentToken)
        external
        view
        override
        returns (uint256 decimals)
    {
        decimals = _paymentDecimalsFor(paymentToken);
    }

    /**
     * @inheritdoc ICrowdsale
     */
    function paymentRateFor(address paymentToken)
        external
        view
        override
        returns (uint256 rate)
    {
        rate = _paymentRateFor(paymentToken);
    }

    /**
     * @inheritdoc ICrowdsale
     */
    function paymentWeiAmountFor(
        address paymentToken,
        uint256 purchaseWeiAmount
    ) external view override returns (uint256 paymentWeiAmount) {
        paymentWeiAmount = _paymentWeiAmountFor(paymentToken, purchaseWeiAmount);
    }

    /**
     * @inheritdoc ICrowdsale
     */
    function purchaseWeiAmountFor(address paymentToken, uint256 paymentWeiAmount)
        external
        view
        override
        returns (uint256 purchaseWeiAmount)
    {
        purchaseWeiAmount = _purchaseWeiAmountFor(paymentToken, paymentWeiAmount);
    }

    /**
     * @inheritdoc ICrowdsale
     */
    function weiRaisedFor(address paymentToken)
        external
        view
        override
        returns (uint256 weiRaised)
    {
        weiRaised = _weiRaisedFor(paymentToken);
    }

    /**
     * @inheritdoc ICrowdsale
     */
    function isPaymentToken(address paymentToken)
        public
        view
        override
        returns (bool isPaymentToken_)
    {
        require(
            paymentToken != NATIVE_TOKEN_ADDRESS || allowNativePaymentToken,
            "Crowdsale: zero payment token"
        );

        isPaymentToken_ = _isPaymentTokens[paymentToken];
    }

    /**
     * @dev Source of tokens. Override this method to modify the way in which the crowdsale ultimately gets and sends
     * its tokens.
     * param beneficiary Address receiving the tokens to be purchased
     * param purchaseWeiAmount Number of tokens to be emitted in wei
     */
    function _deliverTokens(
        address, /* beneficiary */
        uint256 /* purchaseWeiAmount */
    ) internal virtual {
        // solhint-disable-previous-line no-empty-blocks
    }

    /**
     * @dev Determines how payment token is stored/forwarded on purchases.
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Amount in wei of payment token
     */
    function _forwardFunds(address paymentToken, uint256 paymentWeiAmount)
        internal
        virtual
    {
        if (paymentToken == NATIVE_TOKEN_ADDRESS) {
            Address.sendValue(payable(adminWallet()), paymentWeiAmount);
        } else {
            IERC20(paymentToken).transferTokensFromSenderToAccount(
                _paymentDecimalsFor(paymentToken),
                paymentWeiAmount,
                adminWallet()
            );
        }
    }

    /**
     * @dev low level token purchase ***DO NOT OVERRIDE***
     * This function has a non-reentrancy guard, so it shouldn't be called by
     * another `nonReentrant` function.
     * @param beneficiary Recipient of the token purchase
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Payment token amount in wei
     * @param nonEvmAddress Recipient address on non-EVM blockchain
     */
    function _participateCrowdsaleFor(
        address beneficiary,
        address paymentToken,
        uint256 paymentWeiAmount,
        string calldata nonEvmAddress
    ) internal nonReentrant {
        require(
            beneficiary != address(0),
            "Crowdsale: zero beneficiary"
        );
        require(paymentWeiAmount > 0, "Crowdsale: zero payment");
        require(
            (!requireNonEvmAddress && bytes(nonEvmAddress).length == 0)
                || (requireNonEvmAddress && bytes(nonEvmAddress).length > 0),
            "Crowdsale: non-EVM address"
        );

        // calculate crowdsale token wei amount to be sold
        uint256 purchaseWeiAmount = _purchaseWeiAmountFor(paymentToken, paymentWeiAmount);
        require(purchaseWeiAmount > 0, "Crowdsale: zero purchase");

        _preValidatePurchase(beneficiary, paymentToken, paymentWeiAmount, purchaseWeiAmount);

        // update state
        _weiRaised[paymentToken] += paymentWeiAmount;
        crowdsaleTokensWeiSold += purchaseWeiAmount;

        _updatePurchasingState(
            beneficiary,
            paymentToken,
            paymentWeiAmount,
            purchaseWeiAmount
        );

        emit CrowdsaleTokensPurchased(
            msg.sender,
            beneficiary,
            paymentToken,
            paymentWeiAmount,
            purchaseWeiAmount,
            nonEvmAddress
        );

        _processPurchase(beneficiary, purchaseWeiAmount);
        _forwardFunds(paymentToken, paymentWeiAmount);
        _postValidatePurchase(
            beneficiary,
            paymentToken,
            paymentWeiAmount,
            purchaseWeiAmount
        );
    }

    /**
     * @dev Executed when a purchase has been validated and is ready to be executed. Doesn't necessarily emit/send
     * tokens.
     * @param beneficiary Address receiving the tokens
     * @param purchaseWeiAmount Number of tokens to be purchased in wei
     */
    function _processPurchase(address beneficiary, uint256 purchaseWeiAmount)
        internal
        virtual
    {
        _deliverTokens(beneficiary, purchaseWeiAmount);
    }

    /**
     * @dev Override for extensions that require an internal state to check for validity (current user contributions,
     * etc.)
     * @param beneficiary Address receiving the tokens
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Amount in wei of payment token
     * @param purchaseWeiAmount Number of tokens to be purchased in wei
     */
    function _updatePurchasingState(
        address beneficiary,
        address paymentToken,
        uint256 paymentWeiAmount,
        uint256 purchaseWeiAmount
    ) internal virtual {
        // solhint-disable-previous-line no-empty-blocks
    }

    /**
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @return decimals how many decimals for payment token
     */
    function _paymentDecimalsFor(address paymentToken)
        internal
        view
        virtual
        returns (uint256 decimals)
    {
        require(
            isPaymentToken(paymentToken),
            "Crowdsale: invalid payment token"
        );

        decimals = _paymentDecimals[paymentToken];
    }

    /**
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @return rate_ how many weis one token costs for specified payment token
     */
    function _paymentRateFor(address paymentToken)
        internal
        view
        virtual
        returns (uint256 rate_)
    {
        require(
            isPaymentToken(paymentToken),
            "Crowdsale: invalid payment token"
        );

        rate_ = _paymentRates[paymentToken];
    }

    /**
     * @dev Override to extend the way in which crowdsale token is converted to payment tokens.
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param purchaseWeiAmount Number of tokens being sold in wei
     * @return paymentWeiAmount Amount in wei of payment token
     */
    function _paymentWeiAmountFor(
        address paymentToken,
        uint256 purchaseWeiAmount
    ) internal view virtual returns (uint256 paymentWeiAmount) {
        uint256 rate = _paymentRateFor(paymentToken);
        paymentWeiAmount = (purchaseWeiAmount * rate) / TOKEN_SELLING_SCALE;
    }

    /**
     * @dev Validation of an executed purchase. Observe state and use revert statements to undo/rollback when valid
     * conditions are not met.
     * @param beneficiary Address performing the token purchase
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Amount in wei of payment token
     * @param purchaseWeiAmount Number of tokens to be purchased in wei
     */
    function _postValidatePurchase(
        address beneficiary,
        address paymentToken,
        uint256 paymentWeiAmount,
        uint256 purchaseWeiAmount
    ) internal view virtual {
        // solhint-disable-previous-line no-empty-blocks
    }

    /**
     * @dev Validation of an incoming purchase. Use require statements to revert state when conditions are not met.
     * Use `super` in contracts that inherit from Crowdsale to extend their validations.
     * Example from CappedCrowdsale.sol's _preValidatePurchase method:
     *     super._preValidatePurchase(beneficiary, weiAmount);
     *     require(weiRaised().add(weiAmount) <= cap);
     * @param beneficiary Address performing the token purchase
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Amount in wei of payment token
     * @param purchaseWeiAmount Number of tokens to be purchased in wei
     */
    function _preValidatePurchase(
        address beneficiary,
        address paymentToken,
        uint256 paymentWeiAmount,
        uint256 purchaseWeiAmount
    ) internal view virtual {
        // solhint-disable-previous-line no-empty-blocks
    }

    /**
     * @dev Override to extend the way in which payment token is converted to crowdsale tokens.
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Amount in wei of payment token
     * @return purchaseWeiAmount Number of tokens being sold in wei
     */
    function _purchaseWeiAmountFor(address paymentToken, uint256 paymentWeiAmount)
        internal
        view
        virtual
        returns (uint256 purchaseWeiAmount)
    {
        uint256 rate = _paymentRateFor(paymentToken);
        purchaseWeiAmount = (paymentWeiAmount * TOKEN_SELLING_SCALE) / rate;
    }

    /**
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @return weiRaised_ the amount of wei raised
     */
    function _weiRaisedFor(address paymentToken)
        internal
        view
        virtual
        returns (uint256 weiRaised_)
    {
        require(
            isPaymentToken(paymentToken),
            "Crowdsale: invalid payment token"
        );

        weiRaised_ = _weiRaised[paymentToken];
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title AdminPrivileges Interface
 * @author Tim Loh
 * @notice Interface for admin privileges role definitions that are inherited by other contracts
 */
interface IAdminPrivileges {
    // solhint-disable func-name-mixedcase

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function BACKOFFICE_ROLE_ADMIN_ROLE() external view returns (bytes32);

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function BACKOFFICE_GOVERNANCE_ROLE() external view returns (bytes32);

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function BACKOFFICE_CONTRACT_ADMIN_ROLE() external view returns (bytes32);

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function TENANT_ROLE_ADMIN_ROLE() external view returns (bytes32);

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function TENANT_GOVERNANCE_ROLE() external view returns (bytes32);

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function TENANT_CONTRACT_ADMIN_ROLE() external view returns (bytes32);

    // solhint-enable func-name-mixedcase
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title AdminWallet Interface
 * @author Tim Loh
 * @notice Interface for admin wallet that will receive the funds
 */
interface IAdminWallet {
    /**
     * @notice Emitted when admin wallet has been changed from `oldWallet` to `newWallet`
     * @param oldWallet The wallet before the wallet was changed
     * @param newWallet The wallet after the wallet was changed
     * @param sender The address that changes the admin wallet
     */
    event AdminWalletChanged(address indexed oldWallet, address indexed newWallet, address indexed sender);

    /**
     * @notice Returns the admin wallet address that will receive the funds
     * @return Admin wallet address
     */
    function adminWallet() external view returns (address);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title ICappedCrowdsaleHelper
 * @author Tim Loh
 */
interface ICappedCrowdsaleHelper {
    /**
     * @notice Emitted when crowdsale token wei cap has been changed from `oldTokenWeiCap` to `newTokenWeiCap`
     * @param sender The address that changes the token wei cap
     * @param newTokenWeiCap The token wei cap after the change
     * @param oldTokenWeiCap The token wei cap before the change
     */
    event CrowdsaleCapChanged(address indexed sender, uint256 newTokenWeiCap, uint256 oldTokenWeiCap);

    /**
     * @notice Checks whether the crowdsale token cap has been reached
     * @param tokensWeiSold Number of crowdsale tokens sold in wei
     * @return tokenCapReached `true` if crowdsale token cap was reached
     */
    function crowdsaleTokenCapReached(uint256 tokensWeiSold) external view returns (bool tokenCapReached);

    /**
     * @notice Returns the crowdsale token wei cap
     * @return tokenWeiCap the token cap in wei of the crowdsale
     */
    function crowdsaleTokenWeiCap() external view returns (uint256 tokenWeiCap);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {IAdminWallet} from "./IAdminWallet.sol";

/**
 * @title ICrowdsale
 * @author Tim Loh
 */
interface ICrowdsale is IAdminWallet {
    struct PaymentTokenInfo {
        address paymentToken;
        uint256 paymentDecimals;
        uint256 paymentRate;
    }

    /**
     * @notice Emitted when tokens have been purchased
     * @param purchaser who paid for the tokens
     * @param beneficiary who got the tokens
     * @param paymentToken address of ERC20 token used for payment,
     *                     0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount weis paid for purchase
     * @param purchasedWeiAmount weis of crowdsale tokens purchased
     * @param nonEvmAddress recipient address on non-EVM blockchain
     */
    event CrowdsaleTokensPurchased(
        address indexed purchaser,
        address indexed beneficiary,
        address indexed paymentToken,
        uint256 paymentWeiAmount,
        uint256 purchasedWeiAmount,
        string nonEvmAddress
    );

    /**
     * @return `true` if native payment token is allowed
     */
    function allowNativePaymentToken() external view returns (bool);

    /**
     * @return The wei amount of crowdsale tokens sold
     */
    function crowdsaleTokensWeiSold() external view returns (uint256);

    /**
     * @return tokenList the payment tokens, 0x0000000000000000000000000000000000000000 for native token
     */
    function getPaymentTokenAddresses()
        external
        view
        returns (address[] memory tokenList);

    /**
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @return isPaymentToken_ `true` if token is accepted for payment
     */
    function isPaymentToken(address paymentToken)
        external
        view
        returns (bool isPaymentToken_);

    /**
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @return decimals how many decimals for payment token
     */
    function paymentDecimalsFor(address paymentToken) external view returns (uint256 decimals);

    /**
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @return rate_ how many weis one token costs for specified payment token
     */
    function paymentRateFor(address paymentToken) external view returns (uint256 rate_);

    /**
     * @notice Get wei amount of payment tokens required to purchase specified wei amount of crowdsale tokens.
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param purchaseWeiAmount Number of crowdsale tokens being sold in wei
     * @return paymentWeiAmount Amount in wei of payment token
     */
    function paymentWeiAmountFor(
        address paymentToken,
        uint256 purchaseWeiAmount
    ) external view returns (uint256 paymentWeiAmount);

    /**
     * @notice Get wei amount of crowdsale tokens being sold for specified wei amount of payment tokens.
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Amount in wei of payment token
     * @return purchaseWeiAmount Number of crowdsale tokens being sold in wei
     */
    function purchaseWeiAmountFor(address paymentToken, uint256 paymentWeiAmount)
        external
        view
        returns (uint256 purchaseWeiAmount);

    /**
     * @return `true` if require non-EVM address to participate in crowdsale
     */
    function requireNonEvmAddress() external view returns (bool);

    /**
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @return weiRaised_ the amount of wei raised
     */
    function weiRaisedFor(address paymentToken)
        external
        view
        returns (uint256 weiRaised_);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title IFactoryImplementation
 * @author Tim Loh
 * @notice Provides factory implementation type that is inherited by reference implementation contracts for matching
 *         with corresponding factory contracts
 */
interface IFactoryImplementation {
    function factoryImplementationType() external view returns (uint256);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";
import {IAdminPrivileges} from "./IAdminPrivileges.sol";
import {IAdminWallet} from "./IAdminWallet.sol";
import {ICappedCrowdsaleHelper} from "./ICappedCrowdsaleHelper.sol";
import {ICrowdsale} from "./ICrowdsale.sol";
import {IFactoryImplementation} from "./IFactoryImplementation.sol";
import {ILotsCrowdsaleHelper} from "./ILotsCrowdsaleHelper.sol";
import {ITimedCrowdsaleHelper} from "./ITimedCrowdsaleHelper.sol";
import {IWhitelistCrowdsaleHelper} from "./IWhitelistCrowdsaleHelper.sol";

/**
 * @title ILaunchpadCrowdsaleDefault
 * @author Tim Loh
 * @notice Interface for launchpad crowdsale
 */
interface ILaunchpadCrowdsaleDefault is
    IAccessControl,
    IAdminPrivileges,
    IAdminWallet,
    IFactoryImplementation,
    ICappedCrowdsaleHelper,
    ILotsCrowdsaleHelper,
    ITimedCrowdsaleHelper,
    IWhitelistCrowdsaleHelper,
    ICrowdsale
{
    /**
     * @notice Add whitelisted account
     * @dev Must be called by backoffice contract admin role
     * @param account The address to add to whitelist
     * @param weiAmount The allocated wei amount of crowdsale tokens for `account`
     */
    function addWhitelistedAccount(address account, uint256 weiAmount) external;

    /**
     * @notice Add whitelisted accounts
     * @dev Must be called by backoffice contract admin role
     * @param accounts The addresses to add to whitelist
     * @param weiAmounts The corresponding allocated wei amounts of crowdsale tokens for `accounts`
     */
    function addWhitelistedAccounts(
        address[] memory accounts,
        uint256[] memory weiAmounts
    ) external;

    /**
     * @notice Cancel crowdsale window
     * @dev Must be called by backoffice contract admin role
     * @dev Can only cancel when crowdsale window has not started yet
     */
    function cancelCrowdsaleWindow() external;

    /**
     * @notice Extend crowdsale window
     * @dev Must be called by backoffice contract admin role
     * @dev Can only extend when crowdsale window is open
     * @param newEndTimestamp New crowdsale window end timestamp in seconds
     */
    function extendCrowdsaleWindow(uint256 newEndTimestamp) external;

    /**
     * @notice Participate in crowdsale with ERC20 tokens
     * @param paymentToken ERC20 payment token address
     * @param lots Number of lots of crowdsale token being sold
     * @param nonEvmAddress Recipient address on non-EVM blockchain
     */
    function participateCrowdsaleWithErc20(address paymentToken, uint256 lots, string calldata nonEvmAddress) external;

    /**
     * @notice Participate in crowdsale with native tokens
     * @param nonEvmAddress Recipient address on non-EVM blockchain
     */
    function participateCrowdsaleWithNative(string calldata nonEvmAddress) external payable;

    /**
     * @notice Pause user functions
     * @dev Must be called by backoffice contract admin role
     */
    function pauseContract() external;

    /**
     * @notice Remove whitelisted account
     * @dev Must be called by backoffice contract admin role
     * @param account The address to remove from whitelist
     */
    function removeWhitelistedAccount(address account) external;

    /**
     * @notice Remove whitelisted accounts
     * @dev Must be called by backoffice contract admin role
     * @param accounts The addresses to remove from whitelist
     */
    function removeWhitelistedAccounts(address[] memory accounts) external;

    /**
     * @notice Change admin wallet that will receive funds to a new wallet address
     * @dev Must be called by backoffice governance role
     * @param newWallet The new admin wallet
     */
    function setAdminWallet(address newWallet) external;

    /**
     * @notice Set crowdsale token cap in wei
     * @dev Must be called by backoffice contract admin role
     * @param newTokenWeiCap The new token cap in wei for the crowdsale
     */
    function setCrowdsaleTokenWeiCap(uint256 newTokenWeiCap) external;

    /**
     * @notice Set crowdsale window
     * @dev Must be called by backoffice contract admin role
     * @param startTimestamp Timestamp in seconds when crowdsale window will start
     * @param endTimestamp Timestamp in seconds when crowdsale window will end
     */
    function setCrowdsaleWindow(uint256 startTimestamp, uint256 endTimestamp) external;

    /**
     * @notice Set lot size in wei
     * @dev Must be called by backoffice contract admin role
     * @param newLotWeiSize The new lot size in wei
     */
    function setLotWeiSize(uint256 newLotWeiSize) external;

    /**
     * @notice Unpause user functions
     * @dev Must be called by backoffice contract admin role
     */
    function unpauseContract() external;

    /**
     * @notice Get remaining number of crowdsale tokens
     * @return remainderTokens Remaining number of crowdsale tokens
     */
    function getRemainderWeiCrowdsaleTokens() external view returns (uint256 remainderTokens);

    /**
     * @notice Get amount in wei of payment token for specified `lots` of crowdsale token
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param lots Number of lots of crowdsale token being sold
     * @return paymentWeiAmount Amount in wei of payment token
     */
    function lotsPaymentWeiAmountFor(
        address paymentToken,
        uint256 lots
    ) external view returns (uint256 paymentWeiAmount);

    /**
     * @notice Get number of lots for specified amount in wei of payment token
     * @param paymentToken ERC20 payment token address, 0x0000000000000000000000000000000000000000 for native token
     * @param paymentWeiAmount Amount in wei of payment token
     * @return numLots Number of lots of crowdsale token
     */
    function numLotsForPayment(
        address paymentToken,
        uint256 paymentWeiAmount
    ) external view returns (uint256 numLots);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title ILotsCrowdsaleHelper
 * @author Tim Loh
 */
interface ILotsCrowdsaleHelper {
    /**
     * @notice Emitted when lot size has been changed from `oldLotWeiSize` to `newLotWeiSize`
     * @param sender The address that changes the lot size
     * @param newLotWeiSize The lot size in wei after the change
     * @param oldLotWeiSize The lot size in wei before the change
     */
    event LotSizeChanged(address indexed sender, uint256 newLotWeiSize, uint256 oldLotWeiSize);

    /**
     * @notice Returns the lot size in wei
     * @return weiLotSize The lot size in wei
     */
    function lotWeiSize() external view returns (uint256 weiLotSize);

    /**
     * @notice Returns the num of lots for specified token amount in wei
     * @param tokenWeiAmount The amount of tokens in wei
     * @return numLots The number of lots
     */
    function numLotsForToken(uint256 tokenWeiAmount) external view returns (uint256 numLots);

    /**
     * @notice Get number of crowdsale tokens in wei for specified `lots` of crowdsale token
     * @param lots Number of lots of crowdsale token being sold
     * @return tokenWeiAmount Number of crowdsale tokens in wei that will be purchased
     */
    function totalWeiAmountFor(uint256 lots) external view returns (uint256 tokenWeiAmount);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title ITimedCrowdsaleHelper
 * @author Tim Loh
 */
interface ITimedCrowdsaleHelper {
    struct Timeframe {
        uint256 startTimestamp;
        uint256 endTimestamp;
    }

    /**
     * @notice Emitted when crowdsale window has been cancelled
     * @param sender The address that cancelled the crowdsale
     * @param cancelledStartTimestamp Timestamp in seconds when cancelled refund window will start
     * @param cancelledEndTimestamp Timestamp in seconds when cancelled refund window will end
     */
    event CrowdsaleWindowCancelled(
        address indexed sender,
        uint256 cancelledStartTimestamp,
        uint256 cancelledEndTimestamp
    );

    /**
     * @notice Emitted when crowdsale window has been extended
     * @param sender The address that extended the crowdsale window
     * @param newEndTimestamp Timestamp in seconds when crowdsale window will end after extension
     * @param oldEndTimestamp Timestamp in seconds when crowdsale window will end before extension
     */
    event CrowdsaleWindowExtended(
        address indexed sender,
        uint256 newEndTimestamp,
        uint256 oldEndTimestamp
    );

    /**
     * @notice Emitted when crowdsale window has been set
     * @param sender The address that set the crowdsale window
     * @param startTimestamp Timestamp in seconds when crowdsale window will start after set
     * @param endTimestamp Timestamp in seconds when crowdsale window will end after set
     * @param oldStartTimestamp Timestamp when crowdsale window will start before set
     * @param oldEndTimestamp Timestamp when crowdsale window will end before set
     */
    event CrowdsaleWindowSet(
        address indexed sender,
        uint256 startTimestamp,
        uint256 endTimestamp,
        uint256 oldStartTimestamp,
        uint256 oldEndTimestamp
    );

    /**
     * @notice Get crowdsale window
     * @return startTimestamp The start timestamp of crowdsale window
     * @return endTimestamp The end timestamp of crowdsale window
     */
    function getCrowdsaleWindow()
        external
        view
        returns (uint256 startTimestamp, uint256 endTimestamp);

    /**
     * @notice Checks whether the period in which the crowdsale is open has already elapsed.
     * @return hasAlreadyClosed `true` if crowdsale period has elapsed
     */
    function hasCrowdsaleWindowAlreadyClosed() external view returns (bool hasAlreadyClosed);

    /**
     * @notice Check whether crowdsale window has already started now
     * @return hasStarted `true` if crowdsale window already started now
     */
    function hasCrowdsaleWindowAlreadyStarted() external view returns (bool hasStarted);

    /**
     * @notice Check whether crowdsale window has been defined
     * @return isDefined `true` if crowdsale window has been defined
     */
    function isCrowdsaleWindowDefined() external view returns (bool isDefined);

    /**
     * @notice Check whether crowdsale window is open now
     * @return isOpen `true` if crowdsale window is open now
     */
    function isCrowdsaleWindowOpenNow() external view returns (bool isOpen);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title IWhitelistCrowdsaleHelper
 * @author Tim Loh
 */
interface IWhitelistCrowdsaleHelper {
    /**
     * @notice Emitted when allocated amount for account is added to whitelist
     * @param sender The address that added account to whitelist
     * @param account The address of account added to whitelist
     * @param amount The allocated amount for account added to whitelist
     */
    event WhitelistAccountAdded(address sender, address indexed account, uint256 amount);

    /**
     * @notice Emitted when account is removed from whitelist
     * @param sender The address that removed account from whitelist
     * @param account The address of account removed from whitelist
     */
    event WhitelistAccountRemoved(address sender, address indexed account);

    /**
     * @notice Get available number of crowdsale tokens in wei for purchase by `account`
     * @param account The address to check
     * @return availableTokens Available number of crowdsale tokens in wei for purchase by `account`
     */
    function availableTokenWeiFor(address account) external view returns (uint256 availableTokens);

    /**
     * @notice Get max allocated amount for `account`
     * @param account The address to check
     * @return allocatedAmount The max allocated wei amount for `account`
     */
    function beneficiaryWeiCapFor(address account) external view returns (uint256 allocatedAmount);

    /**
     * @notice Returns the amount of crowdsale tokens purchased so far for `account`
     * @param account Address of contributor
     * @return tokensPurchased Crowdsale tokens purchased for `account` so far in wei
     */
    function crowdsaleTokenWeiPurchasedFor(address account) external view returns (uint256 tokensPurchased);

    /**
     * @notice Check whether `account` is whitelisted
     * @param account The address to check
     * @return isWhitelisted_ `true` if `account` is whitelisted
     */
    function isWhitelistedFor(address account) external view returns (bool isWhitelisted_);
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {IERC20, SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {UnitConverter} from "./UnitConverter.sol";

/**
 * @title TransferErc20
 * @author Tim Loh
 * @notice Utility functions to transfer ERC20 tokens from calling contract or sender to given account
 */
library TransferErc20 {
    using SafeERC20 for IERC20;
    using UnitConverter for uint256;

    uint256 public constant TOKEN_MAX_DECIMALS = 18;

    /**
     * @dev Transfer ERC20 tokens from calling contract to given account
     * @param erc20Token The ERC20 token to be transferred
     * @param tokenDecimals The ERC20 token decimal places
     * @param amountWei The amount to transfer in Wei
     * @param toAccount The account to receive the ERC20 tokens
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#dead-code
    // slither-disable-next-line dead-code
    function transferTokensFromContractToAccount(
        IERC20 erc20Token,
        uint256 tokenDecimals,
        uint256 amountWei,
        address toAccount
    ) internal {
        require(tokenDecimals <= TOKEN_MAX_DECIMALS, "TransferErc20: token decimals");
        require(amountWei > 0, "TransferErc20: wei amount");
        require(toAccount != address(0), "TransferErc20: account");

        uint256 amountDecimals = amountWei.scaleWeiToDecimals(tokenDecimals);
        require(amountDecimals > 0, "TransferErc20: decimals amount");

        erc20Token.safeTransfer(toAccount, amountDecimals);
    }

    /**
     * @dev Transfer ERC20 tokens from sender to given account
     * @param erc20Token The ERC20 token to be transferred
     * @param tokenDecimals The ERC20 token decimal places
     * @param amountWei The amount to transfer in Wei
     * @param toAccount The account to receive the ERC20 tokens
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#dead-code
    // slither-disable-next-line dead-code
    function transferTokensFromSenderToAccount(
        IERC20 erc20Token,
        uint256 tokenDecimals,
        uint256 amountWei,
        address toAccount
    ) internal {
        require(tokenDecimals <= TOKEN_MAX_DECIMALS, "TransferErc20: token decimals");
        require(amountWei > 0, "TransferErc20: wei amount");
        require(toAccount != address(0), "TransferErc20: account");

        uint256 amountDecimals = amountWei.scaleWeiToDecimals(tokenDecimals);
        require(amountDecimals > 0, "TransferErc20: decimals amount");

        erc20Token.safeTransferFrom(msg.sender, toAccount, amountDecimals);
    }

    /**
     * @dev Transfer ERC20 tokens from sender to calling contract
     * @param erc20Token The ERC20 token to be transferred
     * @param tokenDecimals The ERC20 token decimal places
     * @param amountWei The amount to transfer in Wei
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#dead-code
    // slither-disable-next-line dead-code
    function transferTokensFromSenderToContract(IERC20 erc20Token, uint256 tokenDecimals, uint256 amountWei) internal {
        transferTokensFromSenderToAccount(erc20Token, tokenDecimals, amountWei, address(this));
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

/**
 * @title UnitConverter
 * @author Tim Loh
 * @notice Converts given amount between Wei and number of decimal places
 */
library UnitConverter {
    uint256 public constant TOKEN_MAX_DECIMALS = 18;

    /**
     * @notice Scale down given amount in Wei to given number of decimal places
     * @param weiAmount Amount in Wei
     * @param decimals Number of decimal places
     * @return decimalsAmount Amount in Wei scaled down to given number of decimal places
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#dead-code
    // slither-disable-next-line dead-code
    function scaleWeiToDecimals(uint256 weiAmount, uint256 decimals) internal pure returns (uint256 decimalsAmount) {
        require(decimals <= TOKEN_MAX_DECIMALS, "UnitConverter: decimals");

        if (decimals < TOKEN_MAX_DECIMALS && weiAmount > 0) {
            uint256 decimalsDiff = TOKEN_MAX_DECIMALS - decimals;
            decimalsAmount = weiAmount / 10 ** decimalsDiff;
        } else {
            decimalsAmount = weiAmount;
        }
    }

    /**
     * @notice Scale up given amount in given number of decimal places to Wei
     * @param decimalsAmount Amount in number of decimal places
     * @param decimals Number of decimal places
     * @return weiAmount Amount in given number of decimal places scaled up to Wei
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#dead-code
    // slither-disable-next-line dead-code
    function scaleDecimalsToWei(uint256 decimalsAmount, uint256 decimals) internal pure returns (uint256 weiAmount) {
        require(decimals <= TOKEN_MAX_DECIMALS, "UnitConverter: decimals");

        if (decimals < TOKEN_MAX_DECIMALS && decimalsAmount > 0) {
            uint256 decimalsDiff = TOKEN_MAX_DECIMALS - decimals;
            weiAmount = decimalsAmount * 10 ** decimalsDiff;
        } else {
            weiAmount = decimalsAmount;
        }
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {Initializable} from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import {ILotsCrowdsaleHelper} from "./interfaces/ILotsCrowdsaleHelper.sol";

/**
 * @title LotsCrowdsaleHelper
 * @author Tim Loh
 * @notice Helper for crowdsale with lots
 */
contract LotsCrowdsaleHelper is Initializable, ILotsCrowdsaleHelper {
    uint256 private _lotWeiSize;

    constructor() {
        _disableInitializers();
    }

    /**
     * @param weiLotSize Lot size in wei
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function __LotsCrowdsaleHelper_init_unchained(
        // solhint-disable-previous-line func-name-mixedcase
        uint256 weiLotSize
    ) internal onlyInitializing {
        require(weiLotSize > 0, "LCH: zero lot size");

        _lotWeiSize = weiLotSize;
    }

    /**
     * @inheritdoc ILotsCrowdsaleHelper
     */
    // solhint-disable-next-line ordering
    function lotWeiSize() public view virtual override returns (uint256 weiLotSize) {
        weiLotSize = _lotWeiSize;
    }

    /**
     * @inheritdoc ILotsCrowdsaleHelper
     */
    function numLotsForToken(uint256 tokenWeiAmount) public view virtual override returns (uint256 numLots) {
        numLots = tokenWeiAmount / lotWeiSize();
    }

    /**
     * @inheritdoc ILotsCrowdsaleHelper
     */
    function totalWeiAmountFor(uint256 lots) public view virtual override returns (uint256 tokenWeiAmount) {
        tokenWeiAmount = lots * lotWeiSize();
    }

    /**
     * @dev Set lot size
     * @param newLotWeiSize The new lot size
     */
    function _setLotWeiSize(uint256 newLotWeiSize) internal virtual {
        require(newLotWeiSize > 0, "LCH: zero lot size");

        uint256 oldLotWeiSize = _lotWeiSize;
        _lotWeiSize = newLotWeiSize;

        emit LotSizeChanged(msg.sender, newLotWeiSize, oldLotWeiSize);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

import {Initializable} from "@openzeppelin/contracts/proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    constructor() {
        _disableInitializers();
    }

    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function __ReentrancyGuard_init_unchained(
        // solhint-disable-previous-line func-name-mixedcase
    ) internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#dead-code
    // slither-disable-next-line dead-code
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {Initializable} from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import {ITimedCrowdsaleHelper} from "./interfaces/ITimedCrowdsaleHelper.sol";

/**
 * @title TimedCrowdsaleHelper
 * @author Tim Loh
 * @dev Helper for crowdsale accepting contributions only within a time frame.
 */
contract TimedCrowdsaleHelper is Initializable, ITimedCrowdsaleHelper {
    Timeframe private _crowdsaleWindow;

    /**
     * @dev Reverts if not in crowdsale time range
     */
    modifier onlyWhileCrowdsaleOpen() {
        require(isCrowdsaleWindowOpenNow(), "TCH: not open");
        _;
    }

    /**
     * @dev Reverts if crowdsale has already started
     */
    modifier onlyBeforeCrowdsaleStart() {
        require(!hasCrowdsaleWindowAlreadyStarted(), "TCH: already started");
        _;
    }

    constructor() {
        _disableInitializers();
    }

    /**
     * @param timeframe Crowdsale opening and closing times
     */
    // https://github.com/crytic/slither/wiki/Detector-Documentation#conformance-to-solidity-naming-conventions
    // slither-disable-next-line naming-convention
    function __TimedCrowdsaleHelper_init_unchained(
        // solhint-disable-previous-line func-name-mixedcase
        Timeframe memory timeframe
    ) internal onlyInitializing {
        require(
            timeframe.startTimestamp > block.timestamp,
            "TCH: start before current time"
        );
        require(
            timeframe.endTimestamp > timeframe.startTimestamp,
            "TCH: end before start time"
        );

        _crowdsaleWindow.startTimestamp = timeframe.startTimestamp;
        _crowdsaleWindow.endTimestamp = timeframe.endTimestamp;
    }

    /**
     * @inheritdoc ITimedCrowdsaleHelper
     */
    // solhint-disable-next-line ordering
    function getCrowdsaleWindow()
        public
        view
        virtual
        override
        returns (uint256 startTimestamp, uint256 endTimestamp)
    {
        startTimestamp = _crowdsaleWindow.startTimestamp;
        endTimestamp = _crowdsaleWindow.endTimestamp;
    }

    /**
     * @inheritdoc ITimedCrowdsaleHelper
     */
    function hasCrowdsaleWindowAlreadyClosed() public view virtual override returns (bool hasAlreadyClosed) {
        hasAlreadyClosed = _crowdsaleWindow.endTimestamp > 0 && block.timestamp > _crowdsaleWindow.endTimestamp;
    }

    /**
     * @inheritdoc ITimedCrowdsaleHelper
     */
    function hasCrowdsaleWindowAlreadyStarted() public view virtual override returns (bool hasStarted) {
        hasStarted = _crowdsaleWindow.startTimestamp > 0 && _crowdsaleWindow.startTimestamp <= block.timestamp;
    }

    /**
     * @inheritdoc ITimedCrowdsaleHelper
     */
    function isCrowdsaleWindowDefined() public view virtual override returns (bool isDefined) {
        isDefined = _crowdsaleWindow.startTimestamp > 0;
    }

    /**
     * @inheritdoc ITimedCrowdsaleHelper
     */
    function isCrowdsaleWindowOpenNow() public view virtual override returns (bool isOpen) {
        isOpen =
            _crowdsaleWindow.startTimestamp > 0 &&
            _crowdsaleWindow.endTimestamp > 0 &&
            block.timestamp >= _crowdsaleWindow.startTimestamp &&
            block.timestamp < _crowdsaleWindow.endTimestamp;
    }

    /**
     * @notice Cancel crowdsale window
     * @dev Can only cancel when refund window has not started yet
     */
    function _cancelCrowdsaleWindow() internal virtual {
        require(isCrowdsaleWindowDefined(), "TCH: no window");
        require(!hasCrowdsaleWindowAlreadyStarted(), "TCH: crowdsale started");

        uint256 oldStartTimestamp = _crowdsaleWindow.startTimestamp;
        uint256 oldEndTimestamp = _crowdsaleWindow.endTimestamp;

        _crowdsaleWindow.startTimestamp = 0;
        _crowdsaleWindow.endTimestamp = 0;

        emit CrowdsaleWindowCancelled(msg.sender, oldStartTimestamp, oldEndTimestamp);
    }

    /**
     * @notice Extend crowdsale window
     * @dev Can only extend when crowdsale window is open
     * @param newEndTimestamp New end timestamp in seconds
     */
    function _extendCrowdsaleWindow(uint256 newEndTimestamp) internal virtual {
        require(newEndTimestamp > block.timestamp, "TCH: before current time");
        require(isCrowdsaleWindowOpenNow(), "TCH: crowdsale not open");

        uint256 oldEndTimestamp = _crowdsaleWindow.endTimestamp;
        require(newEndTimestamp > oldEndTimestamp, "TCH: before old end time");

        _crowdsaleWindow.endTimestamp = newEndTimestamp;

        emit CrowdsaleWindowExtended(msg.sender, newEndTimestamp, oldEndTimestamp);
    }

    /**
     * @notice Set crowdsale window
     * @param startTimestamp Timestamp in seconds when crowdsale window will start
     * @param endTimestamp Timestamp in seconds when crowdsale window will end
     */
    function _setCrowdsaleWindow(uint256 startTimestamp, uint256 endTimestamp) internal virtual {
        require(startTimestamp > block.timestamp, "TCH: start before current time");
        require(endTimestamp > startTimestamp, "TCH: end before start time");
        require(!hasCrowdsaleWindowAlreadyStarted(), "TCH: crowdsale started");

        uint256 oldStartTimestamp = _crowdsaleWindow.startTimestamp;
        uint256 oldEndTimestamp = _crowdsaleWindow.endTimestamp;

        _crowdsaleWindow.startTimestamp = startTimestamp;
        _crowdsaleWindow.endTimestamp = endTimestamp;

        emit CrowdsaleWindowSet(msg.sender, startTimestamp, endTimestamp, oldStartTimestamp, oldEndTimestamp);
    }
}

// SPDX-License-Identifier: Apache-2.0
// Copyright 2023 Enjinstarter
pragma solidity 0.8.19;

import {IWhitelistCrowdsaleHelper} from "./interfaces/IWhitelistCrowdsaleHelper.sol";

/**
 * @title WhitelistCrowdsaleHelper
 * @author Tim Loh
 */
contract WhitelistCrowdsaleHelper is IWhitelistCrowdsaleHelper {
    mapping(address => uint256) private _tokensPurchased;
    mapping(address => uint256) private _whitelistedAccounts;

    modifier beneficiaryCapNotExceeded(
        address beneficiary,
        uint256 purchaseWeiAmount
    ) {
        require(purchaseWeiAmount <= availableTokenWeiFor(beneficiary), "WCH: beneficiary cap exceeded");
        _;
    }

    modifier isWhitelisted(address account) {
        require(isWhitelistedFor(account), "WCH: not in whitelist");
        _;
    }

    /**
     * @inheritdoc IWhitelistCrowdsaleHelper
     */
    function availableTokenWeiFor(address account)
        public
        view
        virtual
        override
        returns (uint256 availableTokens)
    {
        require(account != address(0), "WCH: zero account");

        availableTokens = beneficiaryWeiCapFor(account) - crowdsaleTokenWeiPurchasedFor(account);
    }

    /**
     * @inheritdoc IWhitelistCrowdsaleHelper
     */
    function beneficiaryWeiCapFor(address account)
        public
        view
        virtual
        override
        returns (uint256 allocatedAmount)
    {
        require(account != address(0), "WCH: zero account");

        allocatedAmount = _whitelistedAccounts[account];
    }

    /**
     * @inheritdoc IWhitelistCrowdsaleHelper
     */
    function crowdsaleTokenWeiPurchasedFor(address account)
        public
        view
        virtual
        override
        returns (uint256 tokensPurchased)
    {
        require(account != address(0), "WCH: zero account");

        tokensPurchased = _tokensPurchased[account];
    }

    /**
     * @inheritdoc IWhitelistCrowdsaleHelper
     */
    function isWhitelistedFor(address account)
        public
        view
        virtual
        override
        returns (bool isWhitelisted_)
    {
        require(account != address(0), "WCH: zero account");

        isWhitelisted_ = _whitelistedAccounts[account] > 0;
    }

    /**
     * @notice Add whitelisted account
     * @param account The address to add to whitelist
     * @param weiAmount The allocated wei amount of crowdsale tokens for `account`
     */
    function _addWhitelistedAccount(address account, uint256 weiAmount) internal virtual {
        require(account != address(0), "WCH: zero account");
        require(weiAmount > 0, "WCH: zero amount");
        require(!isWhitelistedFor(account), "WCH: already whitelisted");

        _whitelistedAccounts[account] = weiAmount;

        emit WhitelistAccountAdded(msg.sender, account, weiAmount);
    }

    /**
     * @notice Remove whitelisted account
     * @param account The address to remove from whitelist
     */
    function _removeWhitelistedAccount(address account) internal virtual {
        require(account != address(0), "WCH: zero account");
        require(isWhitelistedFor(account), "WCH: not whitelisted");
        require(crowdsaleTokenWeiPurchasedFor(account) == 0, "WCH: has participated");

        _whitelistedAccounts[account] = 0;

        emit WhitelistAccountRemoved(msg.sender, account);
    }

    /**
     * @notice Update wei amount of crowdsale tokens purchased by `account`
     * @param account Address of contributor
     * @param tokenWeiAmount Amount in wei of token being purchased
     */
    function _updateBeneficiaryTokensPurchased(
        address account,
        uint256 tokenWeiAmount
    ) internal virtual {
        _tokensPurchased[account] += tokenWeiAmount;
    }
}

{
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "libraries": {}
}

[{"inputs":[],"stateMutability":"nonpayable","type":"constructor"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"oldWallet","type":"address"},{"indexed":true,"internalType":"address","name":"newWallet","type":"address"},{"indexed":true,"internalType":"address","name":"sender","type":"address"}],"name":"AdminWalletChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":false,"internalType":"uint256","name":"newTokenWeiCap","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"oldTokenWeiCap","type":"uint256"}],"name":"CrowdsaleCapChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"purchaser","type":"address"},{"indexed":true,"internalType":"address","name":"beneficiary","type":"address"},{"indexed":true,"internalType":"address","name":"paymentToken","type":"address"},{"indexed":false,"internalType":"uint256","name":"paymentWeiAmount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"purchasedWeiAmount","type":"uint256"},{"indexed":false,"internalType":"string","name":"nonEvmAddress","type":"string"}],"name":"CrowdsaleTokensPurchased","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":false,"internalType":"uint256","name":"cancelledStartTimestamp","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"cancelledEndTimestamp","type":"uint256"}],"name":"CrowdsaleWindowCancelled","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":false,"internalType":"uint256","name":"newEndTimestamp","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"oldEndTimestamp","type":"uint256"}],"name":"CrowdsaleWindowExtended","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":false,"internalType":"uint256","name":"startTimestamp","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"endTimestamp","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"oldStartTimestamp","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"oldEndTimestamp","type":"uint256"}],"name":"CrowdsaleWindowSet","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint8","name":"version","type":"uint8"}],"name":"Initialized","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":false,"internalType":"uint256","name":"newLotWeiSize","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"oldLotWeiSize","type":"uint256"}],"name":"LotSizeChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"account","type":"address"}],"name":"Paused","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"bytes32","name":"role","type":"bytes32"},{"indexed":true,"internalType":"bytes32","name":"previousAdminRole","type":"bytes32"},{"indexed":true,"internalType":"bytes32","name":"newAdminRole","type":"bytes32"}],"name":"RoleAdminChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"bytes32","name":"role","type":"bytes32"},{"indexed":true,"internalType":"address","name":"account","type":"address"},{"indexed":true,"internalType":"address","name":"sender","type":"address"}],"name":"RoleGranted","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"bytes32","name":"role","type":"bytes32"},{"indexed":true,"internalType":"address","name":"account","type":"address"},{"indexed":true,"internalType":"address","name":"sender","type":"address"}],"name":"RoleRevoked","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"account","type":"address"}],"name":"Unpaused","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"sender","type":"address"},{"indexed":true,"internalType":"address","name":"account","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"WhitelistAccountAdded","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"sender","type":"address"},{"indexed":true,"internalType":"address","name":"account","type":"address"}],"name":"WhitelistAccountRemoved","type":"event"},{"inputs":[],"name":"BACKOFFICE_CONTRACT_ADMIN_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"BACKOFFICE_GOVERNANCE_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"BACKOFFICE_ROLE_ADMIN_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"DEFAULT_ADMIN_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"MAX_NUM_PAYMENT_TOKENS","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"NATIVE_TOKEN_ADDRESS","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"PERCENT_100_WEI","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"SECONDS_IN_DAY","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"TENANT_CONTRACT_ADMIN_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"TENANT_GOVERNANCE_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"TENANT_ROLE_ADMIN_ROLE","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"TOKEN_MAX_DECIMALS","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"TOKEN_SELLING_SCALE","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"WHITELIST_BATCH_MAX_NUM","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"account","type":"address"},{"internalType":"uint256","name":"weiAmount","type":"uint256"}],"name":"addWhitelistedAccount","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address[]","name":"accounts","type":"address[]"},{"internalType":"uint256[]","name":"weiAmounts","type":"uint256[]"}],"name":"addWhitelistedAccounts","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"adminWallet","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"allowNativePaymentToken","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"availableTokenWeiFor","outputs":[{"internalType":"uint256","name":"availableTokens","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"beneficiaryWeiCapFor","outputs":[{"internalType":"uint256","name":"allocatedAmount","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"cancelCrowdsaleWindow","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"tokensWeiSold","type":"uint256"}],"name":"crowdsaleTokenCapReached","outputs":[{"internalType":"bool","name":"tokenCapReached","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"crowdsaleTokenWeiCap","outputs":[{"internalType":"uint256","name":"tokenWeiCap","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"crowdsaleTokenWeiPurchasedFor","outputs":[{"internalType":"uint256","name":"tokensPurchased","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"crowdsaleTokensWeiSold","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"newEndTimestamp","type":"uint256"}],"name":"extendCrowdsaleWindow","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"factoryImplementationType","outputs":[{"internalType":"uint256","name":"implementationType","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"getCrowdsaleWindow","outputs":[{"internalType":"uint256","name":"startTimestamp","type":"uint256"},{"internalType":"uint256","name":"endTimestamp","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"getPaymentTokenAddresses","outputs":[{"internalType":"address[]","name":"tokenList","type":"address[]"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"getRemainderWeiCrowdsaleTokens","outputs":[{"internalType":"uint256","name":"remainderTokens","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"}],"name":"getRoleAdmin","outputs":[{"internalType":"bytes32","name":"","type":"bytes32"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"grantRole","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"hasCrowdsaleWindowAlreadyClosed","outputs":[{"internalType":"bool","name":"hasAlreadyClosed","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"hasCrowdsaleWindowAlreadyStarted","outputs":[{"internalType":"bool","name":"hasStarted","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"hasRole","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"tokenWeiCap","type":"uint256"},{"internalType":"uint256","name":"weiLotSize","type":"uint256"},{"components":[{"internalType":"address","name":"paymentToken","type":"address"},{"internalType":"uint256","name":"paymentDecimals","type":"uint256"},{"internalType":"uint256","name":"paymentRate","type":"uint256"}],"internalType":"struct ICrowdsale.PaymentTokenInfo[]","name":"paymentTokensInfo","type":"tuple[]"},{"internalType":"bool","name":"isNonEvmAddressRequired","type":"bool"},{"internalType":"bool","name":"allowNativeTokenPayment","type":"bool"},{"components":[{"internalType":"uint256","name":"startTimestamp","type":"uint256"},{"internalType":"uint256","name":"endTimestamp","type":"uint256"}],"internalType":"struct ITimedCrowdsaleHelper.Timeframe","name":"timeframe","type":"tuple"},{"internalType":"address","name":"backofficeAdminAddress","type":"address"}],"name":"initialize","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"isCrowdsaleWindowDefined","outputs":[{"internalType":"bool","name":"isDefined","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"isCrowdsaleWindowOpenNow","outputs":[{"internalType":"bool","name":"isOpen","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"}],"name":"isPaymentToken","outputs":[{"internalType":"bool","name":"isPaymentToken_","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"isWhitelistedFor","outputs":[{"internalType":"bool","name":"isWhitelisted_","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"lotWeiSize","outputs":[{"internalType":"uint256","name":"weiLotSize","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"},{"internalType":"uint256","name":"lots","type":"uint256"}],"name":"lotsPaymentWeiAmountFor","outputs":[{"internalType":"uint256","name":"paymentWeiAmount","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"},{"internalType":"uint256","name":"paymentWeiAmount","type":"uint256"}],"name":"numLotsForPayment","outputs":[{"internalType":"uint256","name":"numLots","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"tokenWeiAmount","type":"uint256"}],"name":"numLotsForToken","outputs":[{"internalType":"uint256","name":"numLots","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"},{"internalType":"uint256","name":"lots","type":"uint256"},{"internalType":"string","name":"nonEvmAddress","type":"string"}],"name":"participateCrowdsaleWithErc20","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"string","name":"nonEvmAddress","type":"string"}],"name":"participateCrowdsaleWithNative","outputs":[],"stateMutability":"payable","type":"function"},{"inputs":[],"name":"pauseContract","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"paused","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"}],"name":"paymentDecimalsFor","outputs":[{"internalType":"uint256","name":"decimals","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"}],"name":"paymentRateFor","outputs":[{"internalType":"uint256","name":"rate","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"},{"internalType":"uint256","name":"purchaseWeiAmount","type":"uint256"}],"name":"paymentWeiAmountFor","outputs":[{"internalType":"uint256","name":"paymentWeiAmount","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"},{"internalType":"uint256","name":"paymentWeiAmount","type":"uint256"}],"name":"purchaseWeiAmountFor","outputs":[{"internalType":"uint256","name":"purchaseWeiAmount","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"removeWhitelistedAccount","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address[]","name":"accounts","type":"address[]"}],"name":"removeWhitelistedAccounts","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"renounceRole","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"requireNonEvmAddress","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"bytes32","name":"role","type":"bytes32"},{"internalType":"address","name":"account","type":"address"}],"name":"revokeRole","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"newWallet","type":"address"}],"name":"setAdminWallet","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"newTokenWeiCap","type":"uint256"}],"name":"setCrowdsaleTokenWeiCap","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"startTimestamp","type":"uint256"},{"internalType":"uint256","name":"endTimestamp","type":"uint256"}],"name":"setCrowdsaleWindow","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"newLotWeiSize","type":"uint256"}],"name":"setLotWeiSize","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bytes4","name":"interfaceId","type":"bytes4"}],"name":"supportsInterface","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"lots","type":"uint256"}],"name":"totalWeiAmountFor","outputs":[{"internalType":"uint256","name":"tokenWeiAmount","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"unpauseContract","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"paymentToken","type":"address"}],"name":"weiRaisedFor","outputs":[{"internalType":"uint256","name":"weiRaised","type":"uint256"}],"stateMutability":"view","type":"function"}]