MATIC Price: $0.99 (+1.78%)
Gas: 46 Gwei
 

Multichain Info

No addresses found
Transaction Hash
Method
Block
From
To
Value
Exec Transaction532875802024-02-08 21:51:4517 days 13 hrs ago1707429105IN
DPEX: Operator MultiSig
0 MATIC0.0026210130.00000193
Exec Transaction532742132024-02-08 13:54:2217 days 21 hrs ago1707400462IN
DPEX: Operator MultiSig
0 MATIC0.0043111755.13153182
Exec Transaction532741502024-02-08 13:52:0817 days 21 hrs ago1707400328IN
DPEX: Operator MultiSig
0 MATIC0.0046366551.18794662
Exec Transaction531454172024-02-05 8:18:5421 days 3 hrs ago1707121134IN
DPEX: Operator MultiSig
0 MATIC0.02631902125.4074978
Exec Transaction519650152024-01-05 10:56:2652 days 33 mins ago1704452186IN
DPEX: Operator MultiSig
0 MATIC0.0187854989.50590306
Exec Transaction512879722023-12-18 22:48:5369 days 12 hrs ago1702939733IN
DPEX: Operator MultiSig
0 MATIC0.0059051467.59940209
Exec Transaction512875672023-12-18 22:33:2669 days 12 hrs ago1702938806IN
DPEX: Operator MultiSig
0 MATIC0.0043886242.01937782
Exec Transaction512868622023-12-18 22:07:1969 days 13 hrs ago1702937239IN
DPEX: Operator MultiSig
0 MATIC0.0060716669.50569191
Exec Transaction512868112023-12-18 22:04:5869 days 13 hrs ago1702937098IN
DPEX: Operator MultiSig
0 MATIC0.7753230647.00588262
Exec Transaction512867662023-12-18 22:03:2269 days 13 hrs ago1702937002IN
DPEX: Operator MultiSig
0 MATIC0.7702677546.69935796
Exec Transaction512867092023-12-18 22:01:2269 days 13 hrs ago1702936882IN
DPEX: Operator MultiSig
0 MATIC0.9345377756.65805068
Exec Transaction512866762023-12-18 22:00:1269 days 13 hrs ago1702936812IN
DPEX: Operator MultiSig
0 MATIC1.0499358963.72000675
Exec Transaction512866402023-12-18 21:58:4869 days 13 hrs ago1702936728IN
DPEX: Operator MultiSig
0 MATIC0.7589538146.06067251
Exec Transaction512865952023-12-18 21:57:1269 days 13 hrs ago1702936632IN
DPEX: Operator MultiSig
0 MATIC0.8020917449.18983377
Exec Transaction512863412023-12-18 21:47:0769 days 13 hrs ago1702936027IN
DPEX: Operator MultiSig
0 MATIC0.9387110858.1393464
Exec Transaction512862802023-12-18 21:44:5769 days 13 hrs ago1702935897IN
DPEX: Operator MultiSig
0 MATIC0.885898553.78718244
Exec Transaction512861792023-12-18 21:41:2369 days 13 hrs ago1702935683IN
DPEX: Operator MultiSig
0 MATIC0.0033444446.19329007
Exec Transaction508534912023-12-07 14:42:5780 days 20 hrs ago1701960177IN
DPEX: Operator MultiSig
0 MATIC0.02173514153.06331446
Exec Transaction507842602023-12-05 21:06:3182 days 14 hrs ago1701810391IN
DPEX: Operator MultiSig
0 MATIC0.0081069977.61234675
Exec Transaction507706232023-12-05 12:41:3882 days 22 hrs ago1701780098IN
DPEX: Operator MultiSig
0 MATIC0.01076668123.25207036
Exec Transaction507680832023-12-05 11:09:2483 days 20 mins ago1701774564IN
DPEX: Operator MultiSig
0 MATIC0.0089715863.19037728
Exec Transaction507679322023-12-05 11:03:5283 days 25 mins ago1701774232IN
DPEX: Operator MultiSig
0 MATIC0.0154195963.17432851
Exec Transaction495869372023-11-05 20:53:56112 days 14 hrs ago1699217636IN
DPEX: Operator MultiSig
0 MATIC0.0035767140.95025145
Exec Transaction495691852023-11-05 10:18:19113 days 1 hr ago1699179499IN
DPEX: Operator MultiSig
0 MATIC0.0913171267.24462446
Exec Transaction495689762023-11-05 10:10:55113 days 1 hr ago1699179055IN
DPEX: Operator MultiSig
0 MATIC0.006055367.65631869
View all transactions

Latest 2 internal transactions

Parent Txn Hash Block From To Value
445495982023-07-01 9:06:21240 days 2 hrs ago1688202381
DPEX: Operator MultiSig
5 MATIC
375497932023-01-01 17:35:06420 days 17 hrs ago1672594506  Contract Creation0 MATIC
Loading...
Loading

Similar Match Source Code
This contract matches the deployed Bytecode of the Source Code for Contract 0xb41268...B3ae124D
The constructor portion of the code might be different and could alter the actual behaviour of the contract

Contract Name:
GnosisSafeProxy

Compiler Version
v0.7.6+commit.7338295f

Optimization Enabled:
No with 200 runs

Other Settings:
default evmVersion, GNU LGPLv3 license
/**
 *Submitted for verification at polygonscan.com on 2021-07-05
*/

/**
 *Submitted for verification at polygonscan.com on 2021-06-16
*/

// SPDX-License-Identifier: LGPL-3.0-only
pragma solidity >=0.7.0 <0.9.0;

/// @title IProxy - Helper interface to access masterCopy of the Proxy on-chain
/// @author Richard Meissner - <[email protected]>
interface IProxy {
    function masterCopy() external view returns (address);
}

/// @title GnosisSafeProxy - Generic proxy contract allows to execute all transactions applying the code of a master contract.
/// @author Stefan George - <[email protected]>
/// @author Richard Meissner - <[email protected]>
contract GnosisSafeProxy {
    // singleton always needs to be first declared variable, to ensure that it is at the same location in the contracts to which calls are delegated.
    // To reduce deployment costs this variable is internal and needs to be retrieved via `getStorageAt`
    address internal singleton;

    /// @dev Constructor function sets address of singleton contract.
    /// @param _singleton Singleton address.
    constructor(address _singleton) {
        require(_singleton != address(0), "Invalid singleton address provided");
        singleton = _singleton;
    }

    /// @dev Fallback function forwards all transactions and returns all received return data.
    fallback() external payable {
        // solhint-disable-next-line no-inline-assembly
        assembly {
            let _singleton := and(sload(0), 0xffffffffffffffffffffffffffffffffffffffff)
            // 0xa619486e == keccak("masterCopy()"). The value is right padded to 32-bytes with 0s
            if eq(calldataload(0), 0xa619486e00000000000000000000000000000000000000000000000000000000) {
                mstore(0, _singleton)
                return(0, 0x20)
            }
            calldatacopy(0, 0, calldatasize())
            let success := delegatecall(gas(), _singleton, 0, calldatasize(), 0, 0)
            returndatacopy(0, 0, returndatasize())
            if eq(success, 0) {
                revert(0, returndatasize())
            }
            return(0, returndatasize())
        }
    }
}

/// @title Proxy Factory - Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
/// @author Stefan George - <[email protected]>
contract GnosisSafeProxyFactory {
    event ProxyCreation(GnosisSafeProxy proxy, address singleton);

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param singleton Address of singleton contract.
    /// @param data Payload for message call sent to new proxy contract.
    function createProxy(address singleton, bytes memory data) public returns (GnosisSafeProxy proxy) {
        proxy = new GnosisSafeProxy(singleton);
        if (data.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(data, 0x20), mload(data), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, singleton);
    }

    /// @dev Allows to retrieve the runtime code of a deployed Proxy. This can be used to check that the expected Proxy was deployed.
    function proxyRuntimeCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).runtimeCode;
    }

    /// @dev Allows to retrieve the creation code used for the Proxy deployment. With this it is easily possible to calculate predicted address.
    function proxyCreationCode() public pure returns (bytes memory) {
        return type(GnosisSafeProxy).creationCode;
    }

    /// @dev Allows to create new proxy contact using CREATE2 but it doesn't run the initializer.
    ///      This method is only meant as an utility to be called from other methods
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function deployProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) internal returns (GnosisSafeProxy proxy) {
        // If the initializer changes the proxy address should change too. Hashing the initializer data is cheaper than just concatinating it
        bytes32 salt = keccak256(abi.encodePacked(keccak256(initializer), saltNonce));
        bytes memory deploymentData = abi.encodePacked(type(GnosisSafeProxy).creationCode, uint256(uint160(_singleton)));
        // solhint-disable-next-line no-inline-assembly
        assembly {
            proxy := create2(0x0, add(0x20, deploymentData), mload(deploymentData), salt)
        }
        require(address(proxy) != address(0), "Create2 call failed");
    }

    /// @dev Allows to create new proxy contact and execute a message call to the new proxy within one transaction.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function createProxyWithNonce(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce
    ) public returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        if (initializer.length > 0)
            // solhint-disable-next-line no-inline-assembly
            assembly {
                if eq(call(gas(), proxy, 0, add(initializer, 0x20), mload(initializer), 0, 0), 0) {
                    revert(0, 0)
                }
            }
        emit ProxyCreation(proxy, _singleton);
    }

    /// @dev Allows to create new proxy contact, execute a message call to the new proxy and call a specified callback within one transaction
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    /// @param callback Callback that will be invoced after the new proxy contract has been successfully deployed and initialized.
    function createProxyWithCallback(
        address _singleton,
        bytes memory initializer,
        uint256 saltNonce,
        IProxyCreationCallback callback
    ) public returns (GnosisSafeProxy proxy) {
        uint256 saltNonceWithCallback = uint256(keccak256(abi.encodePacked(saltNonce, callback)));
        proxy = createProxyWithNonce(_singleton, initializer, saltNonceWithCallback);
        if (address(callback) != address(0)) callback.proxyCreated(proxy, _singleton, initializer, saltNonce);
    }

    /// @dev Allows to get the address for a new proxy contact created via `createProxyWithNonce`
    ///      This method is only meant for address calculation purpose when you use an initializer that would revert,
    ///      therefore the response is returned with a revert. When calling this method set `from` to the address of the proxy factory.
    /// @param _singleton Address of singleton contract.
    /// @param initializer Payload for message call sent to new proxy contract.
    /// @param saltNonce Nonce that will be used to generate the salt to calculate the address of the new proxy contract.
    function calculateCreateProxyWithNonceAddress(
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external returns (GnosisSafeProxy proxy) {
        proxy = deployProxyWithNonce(_singleton, initializer, saltNonce);
        revert(string(abi.encodePacked(proxy)));
    }
}

interface IProxyCreationCallback {
    function proxyCreated(
        GnosisSafeProxy proxy,
        address _singleton,
        bytes calldata initializer,
        uint256 saltNonce
    ) external;
}

Contract Security Audit

Contract ABI

[{"inputs":[{"internalType":"address","name":"_singleton","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"stateMutability":"payable","type":"fallback"}]

Deployed Bytecode

0x608060405273ffffffffffffffffffffffffffffffffffffffff600054167fa619486e0000000000000000000000000000000000000000000000000000000060003514156050578060005260206000f35b3660008037600080366000845af43d6000803e60008114156070573d6000fd5b3d6000f3fea2646970667358221220d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b955264736f6c63430007060033

Deployed Bytecode Sourcemap

598:1528:0:-:0;;;1450:42;1446:1;1440:8;1436:57;1630:66;1626:1;1613:15;1610:87;1607:2;;;1727:10;1724:1;1717:21;1766:4;1763:1;1756:15;1607:2;1819:14;1816:1;1813;1800:34;1917:1;1914;1898:14;1895:1;1883:10;1876:5;1863:56;1954:16;1951:1;1948;1933:38;2000:1;1991:7;1988:14;1985:2;;;2032:16;2029:1;2022:27;1985:2;2088:16;2085:1;2078:27

Swarm Source

ipfs://d1429297349653a4918076d650332de1a1068c5f3e07c5c82360c277770b9552

Block Transaction Difficulty Gas Used Reward
View All Blocks Produced

Block Uncle Number Difficulty Gas Used Reward
View All Uncles
Loading...
Loading
Loading...
Loading

Validator Index Block Amount
View All Withdrawals

Txn Hash Block Value Eth2 PubKey Valid
View All Deposits
[ Download: CSV Export  ]
[ Download: CSV Export  ]

A contract address hosts a smart contract, which is a set of code stored on the blockchain that runs when predetermined conditions are met. Learn more about addresses in our Knowledge Base.